Wiki Agenda Contact Version française

VerifyThis @ FM 2012, problem 2

Computes prefix sums of an array, in-place


Authors: Claude Marché / François Bobot

Topics: Array Data Structure / Trees / Ghost code

Tools: Why3

References: VerifyThis @ FM2012

see also the index (by topic, by tool, by reference, by year)


download ZIP archive


The VerifyThis competition at FM2012: Problem 2

see this web page

module PrefixSumRec

   use import int.Int
   use import int.ComputerDivision
   use import int.Power

   use import map.Map as M
   use import array.Array
   use import array.ArraySum

Preliminary lemmas on division by 2 and power of 2


Needed for the proof of phase1_frame and phase1_frame2

  lemma Div_mod_2:
    forall x:int. x >= 0 -> x >= 2 * div x 2 >= x-1

The step must be a power of 2

  predicate is_power_of_2 (x:int) = exists k:int. (k >= 0 /\ x = power 2 k)

  (* needed *)
  lemma is_power_of_2_1:
    forall x:int. is_power_of_2 x -> x > 1 -> 2 * div x 2 = x

Modeling the "upsweep" phase


Shortcuts

  function go_left (left right:int) : int =
    let space = right - left in left - div space 2

  function go_right (left right:int) : int =
    let space = right - left in right - div space 2

Description in a purely logic way the effect of the first phase "upsweep" of the algorithm. The second phase "downsweep" then traverses the array in the same way than the first phase. Hence, the inductive nature of this definition is not an issue.

  inductive phase1 (left:int) (right:int) (a0: array int) (a: array int) =
    | Leaf : forall left right:int, a0 a : array int.
       right = left + 1 ->
       a[left] = a0[left] ->
       phase1 left right a0 a
    | Node : forall left right:int, a0 a : array int.
       right > left + 1 ->
       phase1 (go_left left right) left a0 a ->
       phase1 (go_right left right) right a0 a ->
       a[left] = sum a0 (left-(right-left)+1) (left+1) ->
       phase1 left right a0 a

Frame properties of the "phase1" inductive


frame lemma for "phase1" on fourth argument. needed to prove both upsweep, downsweep and compute_sums

  let rec lemma phase1_frame (left right:int) (a0 a a' : array int) : unit
    requires { forall i:int. left-(right-left) < i < right ->
               a[i] = a'[i]}
    requires { phase1 left right a0 a }
    variant { right-left }
    ensures { phase1 left right a0 a' } =
    if right > left + 1 then begin
       phase1_frame (go_left left right) left a0 a a';
       phase1_frame (go_right left right) right a0 a a'
    end

frame lemma for "phase1" on third argument. needed to prove upsweep and compute_sums

  let rec lemma phase1_frame2 (left right:int) (a0 a0' a : array int) : unit
    requires { forall i:int. left-(right-left) < i < right ->
               a0[i] = a0'[i]}
    requires { phase1 left right a0 a }
    variant { right-left }
    ensures { phase1 left right a0' a } =
    if right > left + 1 then begin
       phase1_frame2 (go_left left right) left a0 a0' a;
       phase1_frame2 (go_right left right) right a0 a0' a
    end

The upsweep phase

First function: modify partially the table and compute some intermediate partial sums

  let rec upsweep (left right: int) (a: array int)
    requires { 0 <= left < right < a.length }
    requires { -1 <= left - (right - left) }
    requires { is_power_of_2 (right - left) }
    variant { right - left }
    ensures { phase1 left right (old a) a }
    ensures { let space = right - left in
      a[right] = sum (old a) (left-space+1) (right+1) /\
      (forall i: int. i <= left-space -> a[i] = (old a)[i]) /\
      (forall i: int. i > right -> a[i] = (old a)[i]) }
  = 'Init:
    let space = right - left in
    if right > left+1 then begin
      upsweep (left - div space 2) left a;
      upsweep (right - div space 2) right a;
      assert { phase1 (left - div space 2) left (at a 'Init) a };
      assert { phase1 (right - div space 2) right (at a 'Init) a };
      assert { a[left] = sum (at a 'Init) (left-(right-left)+1) (left+1) };
      assert { a[right] = sum (at a 'Init) (left+1) (right+1) }
    end;
    a[right] <- a[left] + a[right];
    assert {
      right > left+1 -> phase1 (left - div space 2) left (at a 'Init) a };
    assert {
      right > left+1 -> phase1 (right - div space 2) right (at a 'Init) a }

The downsweep phase


The property we ultimately want to prove

  predicate partial_sum (left:int) (right:int) (a0 a : array int) =
    forall i : int. (left-(right-left)) < i <= right -> a[i] = sum a0 0 i

Second function: complete the partial using the remaining intial value and the partial sum already computed

  let rec downsweep (left right: int) (ghost a0 : array int) (a : array int)
    requires { 0 <= left < right < a.length }
    requires { -1 <= left - (right - left) }
    requires { is_power_of_2 (right - left) }
    requires { a[right] = sum a0 0 (left-(right-left) + 1) }
    requires { phase1 left right a0 a }
    variant  { right - left }
    ensures { partial_sum left right a0 a }
    ensures { forall i: int. i <= left-(right-left) -> a[i] = (old a)[i] }
    ensures { forall i: int. i > right -> a[i] = (old a)[i] }
  = 'Init:
    let tmp = a[right] in
    assert { a[right] = sum a0 0 (left-(right-left) + 1) };
    assert { a[left] = sum a0 (left-(right-left)+1) (left+1) };
    a[right] <- a[right] + a[left];
    a[left] <- tmp;
    assert { a[right] = sum a0 0 (left + 1) };
    if right > left+1 then
    let space = right - left in
    assert { phase1 (go_left left right) left a0 (at a 'Init) };
    assert { phase1 (go_right left right) right a0 (at a 'Init) };
    assert { phase1 (go_right left right) right a0 a };
    downsweep (left - div space 2) left a0 a;
    assert { phase1 (go_right left right) right a0 a };
    downsweep (right - div space 2) right a0 a;
    assert { partial_sum (left - div space 2) left a0 a };
    assert { partial_sum (right - div space 2) right a0 a }

The main procedure

  let compute_sums a
    requires { a.length >= 2 }
    requires { is_power_of_2 a.length }
    ensures { forall i : int. 0 <= i < a.length -> a[i] = sum (old a) 0 i }
  = let a0 = ghost (copy a) in
    let l = a.length in
    let left = div l 2 - 1 in
    let right = l - 1 in
    upsweep left right a;
    (* needed for the precondition of downsweep *)
    assert { phase1 left right a0 a };
    a[right] <- 0;
    downsweep left right a0 a;
    (* needed to prove the post-condition *)
    assert { forall i : int.
      left-(right-left) < i <= right -> a[i] = sum a0 0 i }

A simple test

  let test_harness () =
    let a = make 8 0 in
    (* needed for the precondition of compute_sums *)
    assert { power 2 3 = a.length };
    a[0] <- 3; a[1] <- 1; a[2] <- 7; a[3] <- 0;
    a[4] <- 4; a[5] <- 1; a[6] <- 6; a[7] <- 3;
    compute_sums a;
    assert { a[0] = 0 };
    assert { a[1] = 3 };
    assert { a[2] = 4 };
    assert { a[3] = 11 };
    assert { a[4] = 11 };
    assert { a[5] = 15 };
    assert { a[6] = 16 };
    assert { a[7] = 22 }

  exception BenchFailure

  let bench () raises { BenchFailure -> true } =
    let a = make 8 0 in
    (* needed for the precondition of compute_sums *)
    assert { power 2 3 = a.length };
    a[0] <- 3; a[1] <- 1; a[2] <- 7; a[3] <- 0;
    a[4] <- 4; a[5] <- 1; a[6] <- 6; a[7] <- 3;
    compute_sums a;
    if a[0] <> 0 then raise BenchFailure;
    if a[1] <> 3 then raise BenchFailure;
    if a[2] <> 4 then raise BenchFailure;
    if a[3] <> 11 then raise BenchFailure;
    if a[4] <> 11 then raise BenchFailure;
    if a[5] <> 15 then raise BenchFailure;
    if a[6] <> 16 then raise BenchFailure;
    if a[7] <> 22 then raise BenchFailure;
    a

end

Why3 Proof Results for Project "verifythis_PrefixSumRec"

Theory "verifythis_PrefixSumRec.PrefixSumRec": fully verified in 148.01 s

ObligationsAlt-Ergo (0.99.1)CVC3 (2.4.1)CVC4 (1.4)Z3 (3.2)Z3 (4.3.2)
Div_mod_20.010.020.030.020.02
is_power_of_2_10.010.030.02------
VC for phase1_frame---------------
split_goal_wp
  1. variant decrease0.01---0.02---0.01
2. precondition0.02---0.03---0.01
3. precondition0.01---0.02------
4. variant decrease0.01---0.03---0.01
5. precondition0.01---0.02---0.02
6. precondition0.02---0.02------
7. postcondition------0.06------
8. postcondition---0.04---0.02---
VC for phase1_frame2---------------
split_goal_wp
  1. variant decrease0.01---0.02---0.01
2. precondition0.02---0.04---0.01
3. precondition0.01---0.02------
4. variant decrease0.02---0.03---0.01
5. precondition0.01---0.02---0.01
6. precondition0.02---0.03------
7. postcondition---0.320.27------
8. postcondition---0.04---0.02---
VC for upsweep---------------
split_goal_wp
  1. variant decrease0.02------------
2. precondition0.020.010.022.08---
3. precondition0.010.010.020.020.03
4. precondition0.030.060.04------
5. variant decrease0.02------------
6. precondition0.020.020.020.020.03
7. precondition0.020.020.020.020.03
8. precondition0.010.020.020.020.03
9. assertion2.48---1.02------
10. assertion2.32---0.74------
11. assertion0.520.02---------
12. assertion---0.58---------
13. index in array bounds0.000.000.010.020.02
14. index in array bounds0.010.030.020.000.00
15. index in array bounds0.010.020.010.010.03
16. assertion0.241.722.08------
17. assertion0.040.812.22------
18. postcondition---0.93---0.18---
19. postcondition1.25---0.86------
20. index in array bounds0.010.000.020.000.00
21. index in array bounds0.020.020.010.020.05
22. index in array bounds0.020.020.020.020.02
23. assertion0.000.010.020.020.03
24. assertion0.010.010.010.020.04
25. postcondition0.020.01---0.090.11
26. postcondition0.160.040.34------
VC for downsweep---------------
split_goal_wp
  1. index in array bounds0.030.030.030.040.04
2. assertion0.000.060.010.010.00
3. assertion---0.000.04------
4. index in array bounds0.010.020.020.030.02
5. index in array bounds0.020.030.020.020.03
6. index in array bounds0.010.020.020.030.03
7. index in array bounds0.010.020.010.000.00
8. assertion0.24---0.029.16---
9. assertion0.040.020.02------
10. assertion0.040.020.04------
11. assertion0.12---1.08------
12. variant decrease0.02------------
13. precondition0.010.030.010.020.04
14. precondition0.020.020.030.040.03
15. precondition0.11---0.44------
16. precondition0.010.020.1610.96---
17. precondition---5.16---2.11---
18. assertion---13.356.92------
19. variant decrease0.06------------
20. precondition0.000.020.010.000.00
21. precondition0.020.060.020.020.03
22. precondition0.020.030.010.020.03
23. precondition0.400.090.06------
24. precondition0.030.17---0.01---
25. assertion0.25---3.020.050.05
26. assertion0.030.040.020.020.03
27. postcondition0.742.380.98------
28. postcondition0.406.882.92------
29. postcondition0.118.432.751.130.11
30. postcondition0.020.12---------
31. postcondition0.020.020.020.150.04
32. postcondition0.020.050.020.110.01
VC for compute_sums---------------
split_goal_wp
  1. precondition0.020.010.012.15---
2. precondition0.010.010.030.040.06
3. precondition0.100.030.0410.43---
4. assertion1.070.280.38------
5. index in array bounds0.020.030.020.020.03
6. precondition0.020.020.010.020.03
7. precondition0.020.020.010.030.03
8. precondition0.020.020.020.030.03
9. precondition0.020.030.020.070.05
10. precondition0.020.340.80------
11. assertion0.20---0.520.050.06
12. postcondition---3.000.39------
VC for test_harness---------------
split_goal_wp
  1. array creation size0.010.010.010.000.00
2. assertion0.070.020.040.050.05
3. index in array bounds0.010.010.020.000.00
4. index in array bounds0.020.020.010.000.00
5. index in array bounds0.010.010.010.000.00
6. index in array bounds0.010.020.010.000.00
7. index in array bounds0.020.010.000.000.00
8. index in array bounds0.000.020.010.000.00
9. index in array bounds0.010.010.020.000.00
10. index in array bounds0.010.010.000.000.00
11. precondition0.020.010.010.000.00
12. precondition0.010.030.020.020.03
13. assertion0.020.030.040.020.01
14. assertion0.020.030.061.110.16
15. assertion0.030.030.0316.65---
16. assertion0.020.020.05------
17. assertion0.030.020.03------
18. assertion0.020.020.03------
19. assertion0.020.030.03------
20. assertion0.010.020.131.100.16
VC for bench0.04------------